Contract Address Details

// SPDX-License-Identifier: GPL-3.0-or-later

// Based on ERC20 implementation of @openzeppelin/contracts (v4.5.0):
// https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.5.0/contracts/token/ERC20/ERC20.sol

pragma solidity ^0.8.0;

import {SafeMath} from "@openzeppelin/contracts/utils/math/SafeMath.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

import {MultiCurrency} from "./MultiCurrency.sol";
import {IToken} from "./IToken.sol";

/// @title MultiCurrency Predeploy Contract
/// @author Acala Developers
/// @notice You can use this predeploy contract to call currencies pallet
/// @dev This contracts will interact with currencies pallet
contract Token is IToken {
    using SafeMath for uint256;

    mapping(address => mapping(address => uint256)) private _allowances;

    /// @notice Get the name of the token.
    /// @return Returns the name of the token.
    function name() public view returns (string memory) {
        return MultiCurrency.name();
    }

    /// @notice Get the symbol of the token, usually a shorter version of the name.
    /// @return Returns the symbol of the token.
    function symbol() public view returns (string memory) {
        return MultiCurrency.symbol();
    }

    /// @notice Get the number of decimals used to get its user representation.
    /// @return Returns the number of decimals.
    function decimals() public view returns (uint8) {
        return MultiCurrency.decimals();
    }

    /// @notice Get the amount of tokens in existence.
    /// @return Returns amount of tokens in existence.
    function totalSupply() public view override returns (uint256) {
        return MultiCurrency.totalSupply();
    }

    /// @notice Get the amount of tokens owned by `account`.
    /// @param account The specified user.
    /// @return Returns the amount of tokens owned by `account`.
    function balanceOf(address account) public view override returns (uint256) {
        return MultiCurrency.balanceOf(account);
    }

    /// @notice Moves `amount` tokens from the caller's account to `to`.
    /// @dev It'll emit an {Transfer} event. The caller must have a balance of at least `amount`.
    /// @param to The dest address, it cannot be the zero address.
    /// @param amount The transfer amount.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function transfer(
        address to,
        uint256 amount
    ) public override returns (bool) {
        address owner = msg.sender;
        _transfer(owner, to, amount);
        return true;
    }

    /// @notice Get the remaining number of tokens that `spender` will be allowed to spend.
    /// @param owner The owner address.
    /// @param spender The spender address.
    /// @return Returns the remaining number of tokens.
    /// The `spender` will be allowed to spend on behalf of `owner` through {transferFrom}. This is zero by default.
    function allowance(
        address owner,
        address spender
    ) public view override returns (uint256) {
        return _allowances[owner][spender];
    }

    /// @notice Sets `amount` as the allowance of `spender` over the caller's tokens.
    /// @dev It'll emit an {Approval} event.
    /// If `amount` is the maximum `uint256`, the allowance is not updated on `transferFrom`.
    /// This is semantically equivalent to an infinite approval.
    /// @param spender Approve the spender.
    /// @param amount The approve amount.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function approve(
        address spender,
        uint256 amount
    ) public override returns (bool) {
        address owner = msg.sender;
        _approve(owner, spender, amount);
        return true;
    }

    /// @notice Moves `amount` tokens from `from` to `to` using the allowance mechanism.
    /// `amount` is then deducted from the caller's allowance.
    /// @dev It'll emit an {Transfer} event.
    /// @param from Transfer amount from the address.
    /// The caller must have allowance for ``from``'s tokens of at least `amount`. It cannot be the zero address.
    /// @param to Transfer amount to the address. It cannot be the zero address.
    /// @param amount The transfer amount.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public override returns (bool) {
        address spender = msg.sender;
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /// @dev Atomically increases the allowance granted to `spender` by the caller.
    /// This is an alternative to {approve} that can be used as a mitigation for problems described in {IERC20-approve}.
    /// Emits an {Approval} event indicating the updated allowance.
    /// @param spender It cannot be the zero address.
    /// @param addedValue The added value.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function increaseAllowance(
        address spender,
        uint256 addedValue
    ) public returns (bool) {
        address owner = msg.sender;
        _approve(owner, spender, _allowances[owner][spender] + addedValue);
        return true;
    }

    /// @dev Atomically decreases the allowance granted to `spender` by the caller.
    /// This is an alternative to {approve} that can be used as a mitigation for problems described in {IERC20-approve}.
    /// Emits an {Approval} event indicating the updated allowance.
    /// @param spender must have allowance for the caller of at least `subtractedValue`. It cannot be the zero address.
    /// @param subtractedValue The subtracted value.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function decreaseAllowance(
        address spender,
        uint256 subtractedValue
    ) public returns (bool) {
        address owner = msg.sender;
        uint256 currentAllowance = _allowances[owner][spender];
        require(
            currentAllowance >= subtractedValue,
            "ERC20: decreased allowance below zero"
        );
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /// @inheritdoc IToken
    function transferToAccountId32(
        bytes32 dest,
        uint256 amount
    ) public override returns (bool) {
        address from = msg.sender;
        require(
            dest !=
                0x0000000000000000000000000000000000000000000000000000000000000000,
            "ERC20: transfer to the zero AccountId32"
        );

        MultiCurrency.transferToAccountId(from, dest, amount);
        emit TransferToAccountId32(from, dest, amount);

        return true;
    }

    /// @dev Moves `amount` of tokens from `sender` to `recipient`.
    /// This internal function is equivalent to {transfer}, and can be used to.
    /// e.g. implement automatic token fees, slashing mechanisms, etc.
    /// Emits a {Transfer} event.
    /// @param from must have a balance of at least `amount`. It cannot be the zero address.
    /// @param to It cannot be the zero address.
    function _transfer(address from, address to, uint256 amount) internal {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        MultiCurrency.transfer(from, to, amount);

        emit Transfer(from, to, amount);
    }

    /// @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
    /// This internal function is equivalent to `approve`, and can be used to.
    /// e.g. set automatic allowances for certain subsystems, etc.
    /// Emits an {Approval} event.
    /// @param owner cannot be the zero address.
    /// @param spender cannot be the zero address.
    function _approve(address owner, address spender, uint256 amount) internal {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /// @dev Spend `amount` form the allowance of `owner` toward `spender`.
    /// Does not update the allowance amount in case of infinite allowance.
    /// Revert if not enough allowance is available.
    /// Might emit an {Approval} event.
    function _spendAllowance(
        address owner,
        address spender,
        uint256 amount
    ) internal {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(
                currentAllowance >= amount,
                "ERC20: insufficient allowance"
            );
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/SafeMath.sol)

pragma solidity ^0.8.0;

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is generally not needed starting with Solidity 0.8, since the compiler
 * now has built in overflow checking.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}
          

// SPDX-License-Identifier: GPL-3.0-or-later

// inherit on IERC20 interface of @openzeppelin/contracts (v4.5.0):
// https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.5.0/contracts/token/ERC20/IERC20.sol

pragma solidity ^0.8.0;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

/// @title IToken Predeploy Contract Interface
/// @author Acala Developers
/// @notice You can use this predeploy contract to call currencies pallet
/// @dev The interface through which solidity contracts will interact with currencies pallet
interface IToken is IERC20 {
    /// @notice Transfer event to AccountId32 type account.
    /// @param sender The sender of the transaction.
    /// @param dest The dest AccountId32 type account.
    /// @param amount The transfer amount.
    /// @dev This is Transfer event which transfer AccountId32 type account.
    event TransferToAccountId32(
        address indexed sender,
        bytes32 indexed dest,
        uint256 amount
    );

    /// @notice Moves `amount` tokens from the caller's account to `dest`, which is AccountId32 type account.
    /// @dev It'll emit an {TransferToAccountId32} event. The caller must have a balance of at least `amount`.
    /// @param dest The dest AccountId32 type account, it cannot be the zero AccountId32.
    /// @param amount The transfer amount.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function transferToAccountId32(
        bytes32 dest,
        uint256 amount
    ) external returns (bool);
}
          

// SPDX-License-Identifier: GPL-3.0-or-later

pragma solidity ^0.8.0;

/// @title MultiCurrency Predeploy Contract Library
/// @author Acala Developers
/// @notice You can use this predeploy contract to call currencies pallet
/// @dev This contracts will interact with currencies pallet
library MultiCurrency {
    /// @dev The MultiCurrency precompile address.
    address private constant PRECOMPILE =
        address(0x0000000000000000000000000000000000000400);

    function name() internal view returns (string memory) {
        (bool success, bytes memory returnData) = PRECOMPILE.staticcall(
            abi.encodeWithSignature("name()")
        );
        assembly {
            if eq(success, 0) {
                revert(add(returnData, 0x20), returndatasize())
            }
        }

        return abi.decode(returnData, (string));
    }

    function symbol() internal view returns (string memory) {
        (bool success, bytes memory returnData) = PRECOMPILE.staticcall(
            abi.encodeWithSignature("symbol()")
        );
        assembly {
            if eq(success, 0) {
                revert(add(returnData, 0x20), returndatasize())
            }
        }

        return abi.decode(returnData, (string));
    }

    function decimals() internal view returns (uint8) {
        (bool success, bytes memory returnData) = PRECOMPILE.staticcall(
            abi.encodeWithSignature("decimals()")
        );
        assembly {
            if eq(success, 0) {
                revert(add(returnData, 0x20), returndatasize())
            }
        }

        return abi.decode(returnData, (uint8));
    }

    function totalSupply() internal view returns (uint256) {
        (bool success, bytes memory returnData) = PRECOMPILE.staticcall(
            abi.encodeWithSignature("totalSupply()")
        );
        assembly {
            if eq(success, 0) {
                revert(add(returnData, 0x20), returndatasize())
            }
        }

        return abi.decode(returnData, (uint256));
    }

    function balanceOf(address account) internal view returns (uint256) {
        (bool success, bytes memory returnData) = PRECOMPILE.staticcall(
            abi.encodeWithSignature("balanceOf(address)", account)
        );
        assembly {
            if eq(success, 0) {
                revert(add(returnData, 0x20), returndatasize())
            }
        }

        return abi.decode(returnData, (uint256));
    }

    function transfer(
        address sender,
        address recipient,
        uint256 amount
    ) internal {
        (bool success, bytes memory returnData) = PRECOMPILE.call(
            abi.encodeWithSignature(
                "transfer(address,address,uint256)",
                sender,
                recipient,
                amount
            )
        );
        assembly {
            if eq(success, 0) {
                revert(add(returnData, 0x20), returndatasize())
            }
        }
    }

    function transferToAccountId(
        address sender,
        bytes32 recipient,
        uint256 amount
    ) internal {
        (bool success, bytes memory returnData) = PRECOMPILE.call(
            abi.encodeWithSignature(
                "transferToAccountId(address,bytes32,uint256)",
                sender,
                recipient,
                amount
            )
        );
        assembly {
            if eq(success, 0) {
                revert(add(returnData, 0x20), returndatasize())
            }
        }
    }
}