Contract Address Details

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.17;

// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/SafeMath.sol)

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is generally not needed starting with Solidity 0.8, since the compiler
 * now has built in overflow checking.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}

// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/utils/SafeERC20.sol)

// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Compatible with tokens that require the approval to be set to
     * 0 before setting it to a non-zero value.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

/// @title StableAsset Predeploy Contract Interface
/// @author Acala Developers
/// @notice You can use this predeploy contract to call stable-asset pallet
/// @dev The interface through which solidity contracts will interact with stable-asset pallet
interface IStableAsset {
    /// @notice The stable asset swapped event.
    /// @param sender The sender of the transaction.
    /// @param poolId The ID of the pool.
    /// @param i The array index of the input token in stableAsset tokens.
    /// @param j The array index of the output token in stableAsset tokens.
    /// @param dx The amount of input token.
    /// @param minDY The minimum amount of output token received.
    /// @param assetLength The length of array in stableAsset tokens.
    event StableAssetSwapped(
        address indexed sender,
        uint32 indexed poolId,
        uint32 i,
        uint32 j,
        uint256 dx,
        uint256 minDY,
        uint32 assetLength
    );

    /// @notice The stable asset minted event.
    /// @param sender The sender of the transaction.
    /// @param poolId The ID of the pool.
    /// @param amounts amount of tokens to be put in the pool.
    /// @param minMintAmount amount of minimum pool token received.
    event StableAssetMinted(
        address indexed sender,
        uint32 indexed poolId,
        uint256[] amounts,
        uint256 minMintAmount
    );

    /// @notice The scheduled call event.
    /// @param sender The sender of the transaction.
    /// @param poolId The ID of the pool.
    /// @param redeemAmount The amount of pool token to be redeemed.
    /// @param amounts The minimum amounts of redeemed token received.
    event StableAssetRedeemed(
        address indexed sender,
        uint32 indexed poolId,
        uint256 redeemAmount,
        uint256[] amounts
    );

    /// @notice The scheduled call event.
    /// @param sender The sender of the transaction.
    /// @param poolId The ID of the pool.
    /// @param redeemAmount The amount of pool token to be redeemed.
    /// @param i The the array index of the input token in stable pool.
    /// @param minRedeemAmount The minimum amount of token recieved.
    /// @param assetLength The length of array of tokens in stable pool.
    event StableAssetRedeemedSingle(
        address indexed sender,
        uint32 indexed poolId,
        uint256 redeemAmount,
        uint32 i,
        uint256 minRedeemAmount,
        uint32 assetLength
    );

    /// @notice The scheduled call event.
    /// @param sender The sender of the transaction.
    /// @param poolId The ID of the pool.
    /// @param amounts The amount of underlying token to be recieved.
    /// @param maxRedeemAmount The maximum amount of pool token to be input.
    event StableAssetRedeemedMulti(
        address indexed sender,
        uint32 indexed poolId,
        uint256[] amounts,
        uint256 maxRedeemAmount
    );

    /// @notice Get stable asset pool tokens.
    /// @param poolId The ID of the pool.
    /// @return poolExists whether pool exists or not.
    /// @return tokens stabel asset pool tokens.
    function getStableAssetPoolTokens(
        uint32 poolId
    ) external view returns (bool, address[] memory);

    /// @notice Get stable asset pool total supply.
    /// @param poolId The ID of the pool.
    /// @return poolExists whether pool exists or not.
    /// @return totalSupply total supply value.
    function getStableAssetPoolTotalSupply(
        uint32 poolId
    ) external view returns (bool, uint256);

    /// @notice Get stable asset pool precision.
    /// @param poolId The ID of the pool.
    /// @return poolExists whether pool exists or not.
    /// @return precision precision value.
    function getStableAssetPoolPrecision(
        uint32 poolId
    ) external view returns (bool, uint256);

    /// @notice Get stable asset pool mint fee.
    /// @param poolId The ID of the pool.
    /// @return poolExists whether pool exists or not.
    /// @return mintFee mint fee value.
    function getStableAssetPoolMintFee(
        uint32 poolId
    ) external view returns (bool, uint256);

    /// @notice Get stable asset pool swap fee.
    /// @param poolId The ID of the pool.
    /// @return poolExists whether pool exists or not.
    /// @return swapFee swap fee value.
    function getStableAssetPoolSwapFee(
        uint32 poolId
    ) external view returns (bool, uint256);

    /// @notice Get stable asset pool redeem fee.
    /// @param poolId The ID of the pool.
    /// @return poolExists whether pool exists or not.
    /// @return redeemFee redeem fee value.
    function getStableAssetPoolRedeemFee(
        uint32 poolId
    ) external view returns (bool, uint256);

    /// @notice Stable asset swap tokens.
    /// @dev It'll emit an {StableAssetSwapped} event.
    /// @param poolId The ID of the pool.
    /// @param i The array index of the input token in stableAsset tokens.
    /// @param j The array index of the output token in stableAsset tokens.
    /// @param dx The amount of input token.
    /// @param minDY The minimum amount of output token received.
    /// @param assetLength The length of array in stableAsset tokens.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function stableAssetSwap(
        uint32 poolId,
        uint32 i,
        uint32 j,
        uint256 dx,
        uint256 minDY,
        uint32 assetLength
    ) external returns (bool);

    /// @notice Stable asset mint.
    /// @dev It'll emit an {StableAssetMinted} event.
    /// @param poolId The ID of the pool.
    /// @param amounts amount of tokens to be put in the pool.
    /// @param minMintAmount amount of minimum pool token received.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function stableAssetMint(
        uint32 poolId,
        uint256[] calldata amounts,
        uint256 minMintAmount
    ) external returns (bool);

    /// @notice Stable asset redeem, redeems the token proportionally.
    /// @dev It'll emit an {StableAssetRedeemed} event.
    /// @param poolId The ID of the pool.
    /// @param redeemAmount The amount of pool token to be redeemed.
    /// @param amounts The minimum amounts of redeemed token received.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function stableAssetRedeem(
        uint32 poolId,
        uint256 redeemAmount,
        uint256[] calldata amounts
    ) external returns (bool);

    /// @notice Stable asset redeem single, Redeems token into single token from pool.
    /// @dev It'll emit an {StableAssetRedeemedSingle} event.
    /// @param poolId The ID of the pool.
    /// @param redeemAmount The amount of pool token to be redeemed.
    /// @param i The the array index of the input token in stable pool.
    /// @param minRedeemAmount The minimum amount of token recieved.
    /// @param assetLength The length of array of tokens in stable pool.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function stableAssetRedeemSingle(
        uint32 poolId,
        uint256 redeemAmount,
        uint32 i,
        uint256 minRedeemAmount,
        uint32 assetLength
    ) external returns (bool);

    /// @notice Stable asset redeem multi, Redeems token into single token from pool.
    /// @dev It'll emit an {StableAssetRedeemedMulti} event.
    /// @param poolId The ID of the pool.
    /// @param amounts The amount of underlying token to be recieved.
    /// @param maxRedeemAmount The maximum amount of pool token to be input.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function stableAssetRedeemMulti(
        uint32 poolId,
        uint256[] calldata amounts,
        uint256 maxRedeemAmount
    ) external returns (bool);
}

/// @title Homa Predeploy Contract Interface
/// @author Acala Developers
/// @notice You can use this predeploy contract to call homa pallet
/// @dev The interface through which solidity contracts will interact with homa pallet
interface IHoma {
    /// @notice Minted liquid currency event.
    /// @param sender The sender of the transaction.
    /// @param amount The minted amount.
    event Minted(address indexed sender, uint256 amount);

    /// @notice Requested redeem event.
    /// @param sender The sender of the transaction.
    /// @param amount The requested amount.
    /// @param fastMatch Allow the request to be fast matched.
    event RequestedRedeem(
        address indexed sender,
        uint256 amount,
        bool fastMatch
    );

    /// @notice Mint liquid currency with staking currency.
    /// @dev It'll emit an {Minted} event.
    /// @param mintAmount The amount of staking currency used to mint liquid currency.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function mint(uint256 mintAmount) external returns (bool);

    /// @notice Request to redeem liquid curency for staking currency.
    /// @dev It'll emit an {RequestedRedeem} event.
    /// @param redeemAmount The amount of liquid currency to be requested  redeemed into Staking currency.
    /// @param fastMatch Allow the request to be fast matched, fast match will take a fixed rate as fee.
    /// @return Returns a boolean value indicating whether the operation succeeded.
    function requestRedeem(
        uint256 redeemAmount,
        bool fastMatch
    ) external returns (bool);

    /// @notice Get exchange rate.
    /// @return returns (exchange_rate), value is FixedU128 with a range of
    /// [0.000000000000000000, 340282366920938463463.374607431768211455]
    function getExchangeRate() external view returns (uint256);

    /// @notice Get estimated reward rate.
    /// @return returns (reward_rate), value is FixedU128 with a range of
    /// [0.000000000000000000, 340282366920938463463.374607431768211455].
    function getEstimatedRewardRate() external view returns (uint256);

    /// @notice Get commission rate.
    /// @return returns (commission_rate) is a FixedU128 representing a decimal.
    function getCommissionRate() external view returns (uint256);

    /// @notice Get fast match fee rate.
    /// @return returns (fast_match_fee) is a FixedU128 representing a decimal.
    function getFastMatchFee() external view returns (uint256);
}

/// @title IWrappedStableAssetShare Interface
/// @author Acala Developers
/// @notice You can use this to wrapped stable asset pool LP token to received market profit.
interface IWrappedStableAssetShare {
    /// @notice Deposit share token to mint wrapped share token.
    /// @param who The sender of the transaction.
    /// @param shareAmount The share token amount to deposit.
    /// @param wrappedShareAmount The wrapped share token amount received.
    event Deposit(address indexed who, uint256 shareAmount, uint256 wrappedShareAmount);

    /// @notice Withdraw share token by burn wrapped share token.
    /// @param who The sender of the transaction.
    /// @param wrappedShareAmount The wrapped share token amount to burn.
    /// @param shareAmount The share token amount received.
    event Withdraw(address indexed who, uint256 wrappedShareAmount, uint256 shareAmount);

    /// @notice Get the deposit rate(the exchange rate for share token to wrapped share token).
    /// @return Returns (exchangeRate). Deposit rate, 1e18 is 100%
    function depositRate() external view returns (uint256);

    /// @notice Get the withdraw rate(the exchange rate for wrapped share token to share token).
    /// @return Returns (exchangeRate). Withdraw rate, 1e18 is 100%
    function withdrawRate() external view returns (uint256);

    /// @notice Deposit `shareAmount` share token to mint wrapped share token.
    /// @param shareAmount The share token amount to deposit.
    /// @return Returns (wrappedShareAmount). The wrapped share token amount received.
    function deposit(uint256 shareAmount) external returns (uint256);

    /// @notice Withdraw share token by burn `wrappedShareAmount` wrapped share token.
    /// @param wrappedShareAmount The wrapped share token amount to burn.
    /// @return Returns (shareAmount). The share token amount received.
    function withdraw(uint256 wrappedShareAmount) external returns (uint256);
}

/// @title IStaking Interface
/// @author Acala Developers
/// @notice You can use this integrate Acala LST staking into your contract.
interface IStaking {
    /// @notice Claim reward from staking pool.
    /// @param sender The sender of the transaction.
    /// @param poolId The index of staking pool.
    /// @param rewardType The reward token address.
    /// @param amount The claimed reward amount.
    event ClaimReward(address indexed sender, uint256 poolId, IERC20 indexed rewardType, uint256 amount);

    /// @notice Unstake share from staking pool.
    /// @param sender The sender of the transaction.
    /// @param poolId The index of staking pool.
    /// @param amount The share amount of unstake.
    event Unstake(address indexed sender, uint256 poolId, uint256 amount);

    /// @notice Stake share into staking pool.
    /// @param sender The sender of the transaction.
    /// @param poolId The index of staking pool.
    /// @param amount The share amount of stake.
    event Stake(address indexed sender, uint256 poolId, uint256 amount);

    /// @notice Get the share token address of the `poolId` pool.
    /// @param poolId The index of staking pool.
    /// @return Returns (shareToken). If pool hasn't been initialized, return address(0x0).
    function shareTypes(uint256 poolId) external view returns (IERC20);

    /// @notice Get the total share amount of the `poolId` pool.
    /// @param poolId The index of staking pool.
    /// @return Returns (totalShare).
    function totalShares(uint256 poolId) external view returns (uint256);

    /// @notice Get the all reward token types of the `poolId` pool.
    /// @param poolId The index of staking pool.
    /// @return Returns (rewardTypesArr). Return all rewarded token types in this pool.
    function rewardTypes(uint256 poolId) external view returns (IERC20[] memory);

    /// @notice Get the share amount of `who` at `poolId` pool.
    /// @param poolId The index of staking pool.
    /// @param who The address of staker.
    /// @return Returns (shareAmount).
    function shares(uint256 poolId, address who) external view returns (uint256);

    /// @notice Get `who`'s unclaimed reward amount of specific `rewardType` at `poolId` pool.
    /// @param poolId The index of staking pool.
    /// @param who The address of staker.
    /// @param rewardType The reward token.
    /// @return Returns (rewardAmount).
    function earned(uint256 poolId, address who, IERC20 rewardType) external view returns (uint256);

    /// @notice Stake share into staking pool.
    /// @param poolId The index of staking pool.
    /// @param amount The share amount to stake.
    /// @return Returns (success).
    function stake(uint256 poolId, uint256 amount) external returns (bool);

    /// @notice Withdraw share from staking pool.
    /// @param poolId The index of staking pool.
    /// @return Returns (success).
    function unstake(uint256 poolId, uint256 amount) external returns (bool);

    /// @notice Claim all rewards from staking pool.
    /// @param poolId The index of staking pool.
    /// @return Returns (success).
    function claimRewards(uint256 poolId) external returns (bool);

    /// @notice Unstake all staked share and claim all unclaimed rewards from staking pool.
    /// @param poolId The index of staking pool.
    /// @return Returns (success).
    function exit(uint256 poolId) external returns (bool);
}

/// @title IStakingTo Interface
/// @author Acala Developers
/// @notice You can use this integrate Acala LST staking into your contract.
interface IStakingTo is IStaking {
    /// @notice Stake share to other.
    /// @param poolId The index of staking pool.
    /// @param amount The share amount to stake.
    /// @param receiver The share receiver.
    /// @return Returns (success).
    function stakeTo(uint256 poolId, uint256 amount, address receiver) external returns (bool);
}

/// @title StableAssetStakeUtil Contract
/// @author Acala Developers
/// @notice Utilitity contract support batch these operation:
/// 1. mint StaleAsset LP token
/// 2. wrap LP token to Wrapped LP token
/// 3. stake Wrapped LP token to Euphrates pool
contract StableAssetStakeUtil {
    using SafeMath for uint256;
    using SafeERC20 for IERC20;

    /// @notice The token address of Euphrates.
    IStakingTo public immutable euphrates;

    /// @notice The StableAsset predeploy contract address.
    IStableAsset public immutable stableAsset;

    /// @notice The Homa predeploy contract address.
    IHoma public immutable homa;

    /// @notice The LDOT token address.
    address public immutable ldot;

    /// @notice Deploys StableAssetStakeUtil contract.
    /// @param euphratesAddr The contract address of Euphrates.
    /// @param stableAssetAddr The contract address of StableAsset predeploy contract.
    /// @param homaAddr The contract address of Homa predeploy contract.
    /// @param ldotAddr The LDOT token address.
    constructor(address euphratesAddr, address stableAssetAddr, address homaAddr, address ldotAddr) {
        euphrates = IStakingTo(euphratesAddr);
        stableAsset = IStableAsset(stableAssetAddr);
        homa = IHoma(homaAddr);
        ldot = ldotAddr;
    }

    /// @notice Mint StalbeAsset LP token and stake it's wrapped token to Euphrates pool.
    /// @param stableAssetPoolId The id of StableAsset pool.
    /// @param assetsAmount The amounts of assets of StableAsset pool used to mint.
    /// @param stableAssetShareToken The LP token of StableAsset pool.
    /// @param wrappedShareToken The wrapper for StableAsset LP token.
    /// @param poolId The if of Euphrates pool.
    /// @return Returns (success).
    function mintAndStake(
        uint32 stableAssetPoolId,
        uint256[] memory assetsAmount,
        IERC20 stableAssetShareToken,
        IWrappedStableAssetShare wrappedShareToken,
        uint256 poolId
    ) public returns (bool) {
        // StableAsset check
        (bool valid, address[] memory assets) = stableAsset.getStableAssetPoolTokens(stableAssetPoolId);
        require(valid && assetsAmount.length == assets.length, "StableAssetStakeUtil: invalid stable asset pool");

        uint256[] memory paramAmounts = assetsAmount;
        // transfer assets from msg.sender
        for (uint256 i = 0; i < assets.length; i++) {
            if (assetsAmount[i] != 0) {
                IERC20(assets[i]).safeTransferFrom(msg.sender, address(this), assetsAmount[i]);
            }
            // convert LDOT amount to rebased LDOT amount as the param
            // NOTE: the precision of Homa.getExchangeRate is 1e18
            if (assets[i] == ldot) {
                paramAmounts[i] = assetsAmount[i].mul(homa.getExchangeRate()).div(1e18);
            }
        }

        // StableAsset mint, no need to approve assets to stable-asset
        uint256 beforeStableAssetShareAmount = IERC20(stableAssetShareToken).balanceOf(address(this));
        // NOTE: allow max slippage here
        bool success = stableAsset.stableAssetMint(stableAssetPoolId, paramAmounts, 0);
        require(success, "StableAssetStakeUtil: stable-asset mint failed");
        uint256 afterStableAssetShareAmount = IERC20(stableAssetShareToken).balanceOf(address(this));
        uint256 mintedShareAmount = afterStableAssetShareAmount.sub(beforeStableAssetShareAmount);
        require(mintedShareAmount != 0, "StableAssetStakeUtil: zero minted share amount is not allowed");

        // wrap share token
        stableAssetShareToken.safeApprove(address(wrappedShareToken), mintedShareAmount);
        uint256 wrappedShareAmount = wrappedShareToken.deposit(mintedShareAmount);
        require(wrappedShareAmount != 0, "StableAssetStakeUtil: zero wrapped share amount is not allowed");

        // stake wrapped share token to Euphrates pool
        IERC20(address(wrappedShareToken)).safeApprove(address(euphrates), wrappedShareAmount);
        return euphrates.stakeTo(poolId, wrappedShareAmount, msg.sender);
    }

    /// @notice Wrap StalbeAsset LP token and stake to Euphrates pool.
    /// @param stableAssetShareToken The LP token of StableAsset pool.
    /// @param amount The amount of LP token.
    /// @param wrappedShareToken The wrapper for StableAsset LP token.
    /// @param poolId The if of Euphrates pool.
    /// @return Returns (success).
    function wrapAndStake(
        IERC20 stableAssetShareToken,
        uint256 amount,
        IWrappedStableAssetShare wrappedShareToken,
        uint256 poolId
    ) public returns (bool) {
        require(amount != 0, "StableAssetStakeUtil: zero share amount is not allowed");
        stableAssetShareToken.safeTransferFrom(msg.sender, address(this), amount);
        stableAssetShareToken.safeApprove(address(wrappedShareToken), amount);
        uint256 wrappedShareAmount = wrappedShareToken.deposit(amount);
        require(wrappedShareAmount != 0, "StableAssetStakeUtil: zero wrapped share amount is not allowed");

        // stake wrapped share token to Euphrates pool
        IERC20(address(wrappedShareToken)).safeApprove(address(euphrates), wrappedShareAmount);
        return euphrates.stakeTo(poolId, wrappedShareAmount, msg.sender);
    }
}